デジタルアニメ端末のAppleScript

2000.03.09作成
2001.02.18更新

　撮影用のMacの設定のために使ったAppleScriptのソースとアプリ。

◎All_UNLOCK1.1.app

◎フォルダをドロップするか選択して実行すると、ファイルロックを外します。フォルダの中まで再帰的に処理します。

my PrePro()

on open (FileList)
	tell application "Finder" to set selection to FileList as list
	my PrePro()
end open

on PrePro()
	tell application "Finder"
		try
			set locked of every file of selection whose locked is true to false
		end try
		try
			my Recurse(folders of selection)
		end try
	end tell
end PrePro

on Recurse(x)
	tell application "Finder"
		repeat with i in x
			try
				set (locked of every file of i whose locked is true) to false
			end try
			try
				my Recurse(folders of i)
			end try
		end repeat
	end tell
end Recurse

◎CoreRETAS_alias1.2

　フォルダをドロップするとCoreRETASのタイムシートファイルのみのエイリアスを一階層上に作る。カットフォルダで別れているタイムシートを連続レコーディングで「全てを選択」ボタンで扱いやすいように。撮影さん向け。

on open (theList)
	my mainF(theList)
end open

on mainF(aliases_dropped)
	tell application "Finder"
		repeat with an_alias in every alias of aliases_dropped
			try
				make new alias file to (every file of an_alias whose file type is "CRDT") at (container of an_alias)
			end try
		end repeat
	end tell
end mainF

◎無理矢理ファイルタイプをLha形式

　WindowsからLZH書庫を貰ったときに、ファイルタイプが設定されていないのを無理に直します。LHA Expanderの使用を想定。

on run
	tell application "Finder"
		my mainFunction(selection)
	end tell
end run

on open theList
	mainFunction(theList)
end open

on mainFunction(theList)
	tell application "Finder"
		repeat with curItem in theList
			set creator type of curItem to "LHAx"
			set file type of curItem to "LHA "
		end repeat
	end tell
end mainFunction

◎RETAS!Pro & AfterEffects FileExchange Set

　RETASとAfterEffectsファイルの拡張子をFileExchangeに登録します。

tell application "File Exchange"
	activate
	set current panel to PC exchange
	make new extension mapping with properties {PC extension:".tgf", creator type:"TRMN", file type:"TMP4"}
	make new extension mapping with properties {PC extension:".t2f", creator type:"TRMN", file type:"TMP3"}
	make new extension mapping with properties {PC extension:".tcf", creator type:"TRMN", file type:"TMTC"}
	make new extension mapping with properties {PC extension:".ccf", creator type:"PAMN", file type:"PMCC"}
	make new extension mapping with properties {PC extension:".crf", creator type:"PAMN", file type:"PMRC"}
	make new extension mapping with properties {PC extension:".tsf", creator type:"CRTS", file type:"CRDT"}
	make new extension mapping with properties {PC extension:".ibf", creator type:"CRTS", file type:"CRSD"}
	make new extension mapping with properties {PC extension:".aep", creator type:"FXTC", file type:"EggP"}
	make new extension mapping with properties {PC extension:".pic", creator type:"ogle", file type:"PICT"}
	make new extension mapping with properties {PC extension:".pct", creator type:"ogle", file type:"PICT"}
	quit
end tell

◎アピアランス設定

　スクロールバーを便利にします。

display dialog "システムフォントはどちらにしますか？" buttons {"Osaka", "Osaka Narrow"} default button 2
set select_font to button returned of result

tell application "Finder"
	activate
	select file "アピアランス" of folder "コントロールパネル" of folder "システムフォルダ" of startup disk
	open selection
	tell application "アピアランス"
		activate
		set font smoothing to false
		set scroll bar arrow style to ﾇconstant ****dublﾈ
		set scroll box style to proportional
		if select_font is "Osaka Narrow" then
			set system font to ".Osaka Narrow"
		else
			set system font to "Osaka"
		end if
		set views font to "Osaka"
		set font smoothing to false
		set collapsible via title bar to true
		quit
	end tell
end tell

◎アプリケーション切換

display dialog "フレームは？" buttons {"有り", "無し"} default button 2
set selbtn_f to button returned of result
display dialog "表示位置は？" buttons {"左上", "左下", "右上"} default button 3
set selbtn to button returned of result

tell application "アプリケーション切替"
	set the icon size of the palette to small
	set the visible of the palette to true
	set the constraint of the palette to all monitors
	set the orientation of the palette to vertical
	set the names visible of the palette to false
	if selbtn_f is "無し" then
		set the frame visible of the palette to false
	else
		set the frame visible of the palette to true
	end if
	if selbtn is "右上" then
		set the position of the palette to upper right
		set the button ordering of the palette to launch order
		set the anchor point of the palette to upper left
	else if selbtn is "左下" then
		set the position of the palette to lower left
		set the button ordering of the palette to reverse launch order
		set the anchor point of the palette to lower right
	else
		set the position of the palette to upper left
		set the button ordering of the palette to launch order
		set the anchor point of the palette to upper right
	end if
	
end tell

POST