VBから起動したアプリケーションを呼び出し元のVBから終了させます。
CreateProcessで起動するバージョンとShellを使って起動する２バージョンを掲載してあります。
Shellを使う方法は、長らくWin9xでのみ動作しNTでは上手く動作しないものを掲載していましたが、AKAISHIさんからご教授頂きどちらでも動くものに変更することができました。AKAISHIさん情報ありがとうございました。
'-------------------------------------------------------
' CreateProcess使用
'-------------------------------------------------------
Private Sub Command1_Click()
Dim udtProcInfo As PROCESS_INFORMATION
Dim udtStartInfo As STARTUPINFO
Dim lngret As Long
udtStartInfo.cb = LenB(udtStartInfo)
lngret = CreateProcess(vbNullString, "calc.exe", ByVal 0&, ByVal 0&, 1&, NORMAL_PRIORITY_CLASS, ByVal 0&, vbNullString, udtStartInfo, udtProcInfo)
MsgBox "[電卓] を終了させます"
Call TerminateProcess(udtProcInfo.hProcess, 0&)
Call CloseHandle(udtProcInfo.hThread)
Call CloseHandle(udtProcInfo.hProcess)
End Sub
'-------------------------------------------------------
' Shell使用
'-------------------------------------------------------
Private Sub Command2_Click()
Dim lngProcessID As Long
Dim hProcess As Long
lngProcessID = Shell("calc.exe", vbNormalFocus)
hProcess = OpenProcess(SYNCHRONIZE Or PROCESS_TERMINATE, True, lngProcessID)
MsgBox "[電卓] を終了させます"
Call TerminateProcess(hProcess, 0&)
Call CloseHandle(hProcess)
End Sub
'-------------------------------------------------------
' Module
'-------------------------------------------------------
Public Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessId As Long
dwThreadId As Long
End Type
Public Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type
Public Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, lpProcessAttributes As Any, lpThreadAttributes As Any, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDriectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Public Declare Function OpenProcess Lib "kernel32.dll" (ByVal dwAccess As Long, ByVal fInherit As Integer, ByVal hObject As Long) As Long
Public Declare Function TerminateProcess Lib "kernel32" (ByVal hProcess As Long, ByVal uExitCode As Long) As Long
Public Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Public Const SYNCHRONIZE = 1048576
Public Const NORMAL_PRIORITY_CLASS = &H20&
Public Const PROCESS_TERMINATE = &H1
DownLoad vbtips100.lzh 3KB (VB6.0)