スライドの切り替え時のエフェクト機能を提供してくれるTransitionManagerと言うクラスがあるので、これを用いたスライドショーの作成が今回のお勉強である。
　 このクラスには、画像切り替え時の効果(トランジション効果)として10個のタイプ（Blinds,Fade,Fly,Iris, hoto,Pixeldissolve, Rotate,Squeeze,Wipe,Zoom）が用意されている。　また、イージングとして６個のクラス（Back,Bounce,Elastic, Regular,Strong,None）と、４個のメソッド（easeIn,easeOut,easeInOut,easeNone）が選択可能である。
　このスライドショーでは、トランジションタイプの８個、イージングクラスの５個のうち一個ずつをランダムに発生させて組み合わせ、トランジション効果を生み出している。　イージングのメソッドは、easeOutに限定している。
　それぞれの効果には、設定できるパラメータがあり（ヘルプなど参照のこと)、すべてが共通ではないが、以下のスクリプトで述べるように、すべてのパラメーターをひとつのTransitionManagerに記述しておくことで共通のスクリプトで使えるようだ。

●340*340、背景色黒のステージ（24fps）を設定
●同じディレクトリのimgフォルダに、300*300の７枚の写真（p1.jpg,p2.jpg,,,,p7.jpg）を格納しておく。（size、枚数は随意)

スクリプト（_root、FRAME1に記述）

import fl.transitions.*;
import fl.transitions.easing.*;
import flash.utils.setInterval;
//写真総枚数
var picTotal:Number=7;
//transitioタイプ、イージングクラスを配列で定義
var transition:Array=new Array(Blinds,Iris,Photo,PixelDissolve,Zoom,Fly,Squeeze,Wipe);
var easetype:Array=new Array(Back,Bounce,Elastic,Regular,Strong);
//写真表示用ムービークリップ
var load_mc:MovieClip = new MovieClip();
addChild(load_mc);
load_mc.x=load_mc.y=20;
//間隔intervalで表示写真の番号を発生させ、loadPic関数に渡す
var n:Number=0;
var interval:Number=3000;
setPic();
function setPic():void {
  if (n>picTotal-1) {
    n=1;
  } else {
    n++;
  }
  loadPic(n);
}
var ID=setInterval(setPic,interval);
//ムービークリップload_mcに画像を読み込み、読み込み完了したら
//transPic関数でトランジション効果を付与する
function loadPic(n):void {
  var mcLoader:Loader = new Loader();
  load_mc.addChild(mcLoader);
  var url:String="img/p"+n+".jpg";
  var urlReq:URLRequest=new URLRequest(url);
  mcLoader.load(urlReq);
  mcLoader.contentLoaderInfo.addEventListener( Event.COMPLETE , transPic);
  function transPic():void {
    var transType:Class=transition[Math.floor(Math.random()*transition.length)];
    var easeType:Class=easetype[Math.floor(Math.random()*easetype.length)];
    var myTransition:TransitionManager=new TransitionManager(load_mc);
    myTransition.startTransition({type:transType, direction:0, duration:2, shape:"CIRCLE", startPoint:2, xSections:20, ySections:20, dimension:1,     easing:easeType.easeOut});
  }
}

import mx.transitions.*;
import mx.transitions.easing.*;


var picTotal = 7;

var transition:Array = new Array(Blinds, Iris, Photo, PixelDissolve, Zoom, Fly, Squeeze, Wipe);
var easetype:Array = new Array(Back, Bounce, Elastic, Regular, Strong);

this.createEmptyMovieClip("load_mc", 1);
load_mc._x = load_mc._y = 20;


var n = 0;
var interval = 3000;
setPic();
function setPic() {
  if (n>picTotal-1) {
    n = 1;
  } else {
    n++;
  }
  loadPic(n);
}
ID = setInterval(setPic, interval);


function loadPic(n) {
  var mcLoader:MovieClipLoader = new MovieClipLoader();
  jpg = "img/p"+n+".jpg";
  mcLoader.loadClip(jpg,load_mc);
  var oListener:Object = new Object();
  oListener.onLoadInit = function() {
    transPic();
  };
  mcLoader.addListener(oListener);
}
function transPic() {
  var transType:Function = transition[Math.floor(Math.random()*transition.length)];
  var easeType:Function = easetype[Math.floor(Math.random()*easetype.length)];
  var myTransition:TransitionManager = new TransitionManager(load_mc);
  myTransition.startTransition({type:transType, direction:0, duration:2, shape:"CIRCLE", startPoint:2, xSections:20, ySections:20, dimension:1, easing:easeType.easeOut});
}