AVR試用記-assembly

　１行目は、カレントドライブをアセンブルソースのあるH:に移します。
　２行目は、カレントディレクトリをソースのあるフォルダに移します。H:以下はフォルダパスのコピペで書けます。
　３行目は、アセンブルの実行です。-fI はインテルhexの指定です。最後はソース名をコピペします。

このように準備しておくとソースファイルのあるフォルダを小さく表示しておき、DOS窓を開いて 0.bat をドラッグアンドドロップとenterキーでアセンブル結果のhexファイルがソースのあるフォルダに生成されます。
通常使用中の画面です。

少しずつプログラムを書いて、実行して確認後に次の段階へ進むのが楽しみ方ですから、
プログラムの追加・修正　→　アセンブル　→　書き込み・実行
を繰り返すことになります。DOS窓を２つあけておけば、移動してＦ３キーだけで作業を続けることができます。（WINAVRでまったく同じ操作をしています。）　なお、ソースエディタは自由ですから自分が読みやすいようにカスタマイズしたエディタを使用できます。

ハードウエアについて：
とりあえずATTiny2313を内蔵RC8MHzで使用することとして専用のブレッドボードを準備しました。現在はPB0～PB7にLEDアレイ（330ΩでGNDへ）を接続しています。出力Hで点灯します。

あとは必要に応じて入力用のスイッチやセンサを増設する予定です。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

３　最初のプログラム　
構想のアセンブルシステムが正常に動くかどうかをテストするために、単にLEDを２個点灯するだけのプログラムです。
結果として思い通りになっていました。
　注）半角の<>は全角の＜＞で書いています。半角に戻す必要があります。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

４　アセンブラ覚え書き　
.CSEG　Codeセグメント＝ここからコードが始まる。　DSEG＝data　ESEG=eeprom

def.incの参照　アセンブラを他のフォルダに置いて実行してもちゃんと探してインクルードしている。不思議。

0b10101010の分割記述　0b1010_1010 や　0b\10_10_10_10のようにアンダースコアを挿入してもよい。

コメント　「；」　「//」　「/*…*/」　いずれも使えます。

サブルーチン　rcallで呼び出し　retで復帰　レジスタ退避に注意

スキップ命令　感覚的にはyesを先に書きたいのですが…
　　sbrs r4,0　　　;スキップ命令　setされていたら　　aaaa　　　　　;NOのとき（rjmp　又は　他の命令）　　bbbb　　　　　;YESのとき（rjmp　又は　他の命令）
Tiny2313割り込みベクタテーブル

チャタリング対策
　タクトスイッチのチャタリングを除去するために、スイッチをPD2にプルアップで繋ぎ、レジスタr3のbit1～0で判定します。スイッチはポーリングで調べ、読み込み後は20msのディレイを取っています。これと0.1uF並列でチャタリングが防止できます。

10ms　waitルーチン
　r22に引数（1で10ms）を書いて呼び出す。r22は内部で変更される。r0,r1,r2を使用。

ROM領域に定数を置く
データはラベルを付けて,csegに置く。読み取りはZレジスタにアドレスを書いて、間接アドレスで読みとる。rレジスタの指定がなければr0に。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

５　ＬＥＤ点滅プログラム　
ポイント：　サブルーチン（rcallで呼び出し　retで復帰　レジスタ退避に注意）

ポートB5のLEDを２秒周期で点滅します。点灯→１秒待ち→消灯→１秒待ち　を繰り返します。ポートのLEDはGNDに繋いでいますからＨで点灯します。
１秒のウエイトルーチン（delay）はサブルーチンをコールします。１秒のサブルーチンは　1ms　か　10ms　の孫サブルーチンを使うのが適当だと思いますが、ここではサブルーチンの構造を簡単にするために一つにまとめています。
ウエイト（ディレー）はよく使われますが、MCUはひたすら時間の計算をしていますので同時に他の処理はできません。能率の悪い方法です。

割り込みテーブルを書いています。tiny2313はresetを含めて19種の割り込みがありますが、これらは0番地～37番地(?)の決まった場所にアクセスするようです。割り込みを使うならその場所には勝手なプログラムは書けませんから予約の意味でテーブルを書いてあります。今回は使いません。したがって、すべての割り込み先はresetにしています。今後割り込みを使うときは該当する割り込みだけジャンプ先を書くことになります。使わない割り込みは　rjmp reset　でなくて　reti（割り込みからの復帰）を書くべきかもしれません、要勉強です。
　注）半角の<>は全角の＜＞で書いています。半角に戻す必要があります。

サブルーチンは３重のループになっています。内側のループは４クロックでできていて、ループ回数は内側が200回、中間が100回、外側が100回ですから、途中のループにかかる処理を無視すると、　４クロック*200*100*100＝8000000クロックとなって、8MHzクロックから１秒かかることになります。尤も、内側のループを回すために５クロックかかり、これが100*100＝10000回ありますから50000クロックは余分にかかります。1%未満ですが、およそ１秒ということにしておきます。
今回はサブルーチン内で使うレジスタはmainでは使っていないので退避はしていません。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

６　スイッチ入力の処理　
ポイント：
●I/Oレジスタのビットを判定する（sbis PINx,2 ;I/Oポートのビットがセットならスキップ sbicもある）
●入力ポートのプルアップ（入力指定のPORTxに１を書くとプルアップされる）

PORTD2-GND間にタクトスイッチを接続して、onの時にPORTB2のLEDが点灯する回路です。他の７個のLEDは常時点灯しています。スイッチ入力の判定を調べるために作ったプログラムです。

この項ではスイッチのチャタリングは考慮していません。また、I/Oポートの処理が最適ではないかと思いますが今後の課題です。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

７　スイッチのトグル動作（ポーリングによる）　
ポイント：
●ONとOFFを調べるだけではトグル動作はできません。数十msでスイッチを読みますから手押しでは何回も連続してONを読むことになります。前回の結果を記憶して、前回はOFFで、今回がONのときだけ押されたと判断します。いくつかのレジスタが必要です。
●チャタリング防止のため10ms以上の読み取り間隔を作りました。（10msのウエイトルーチンを入れています）
●sbrs r4, 1　;r4のbit1がset(H)ならスキップ（skip bit register set?）でレジスタのbitを判断できます。
●sbrc（skip bit register clear?）もあります。全汎用レジスタに使えるようです。
●r0～r15は clr r0 が使えます。0を代入できます。ただし、ser 0xff代入はできません。したがって、１を代入するときに　clr r4　と　inc r4　の２命令で書きました。

点滅の１周期（スイッチのディレイを含めて約0.3秒）の期間はスイッチを読みません。点滅動作中に瞬間的にスイッチを押すとほとんど読みとれません。やや長押しのスイッチングが必要です。

Ｃで同様のルーチンを書いたことがあるのですが、命令を確認しながら（探しながら）のプログラムにかなり苦労しました。試行錯誤の結果できたようなもので、最適なプログラムではないと思います。
勉強の一里塚として記録しておきます。次は割り込み処理で考えてみようと思いますが、割り込みの方が簡単ではないかと思います。
今回は使いませんでしたが、Ｃにおける変数をどのように data segment に置けばいいのか、どのようにアクセスするのかを今後は調べる必要があります。探しても以外にサンプルはないような感じです。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

８　スイッチのトグル動作（割り込みによる）　
ポイント：
●INT1割り込みを使いました。MCUCR=0b0000_1000　(INT0なら 0b0000_0010)いずれも立ち下がりで割り込み。
GIMSK=0b1000_0000(INT0なら0b0100_0000）他にSREGで　割り込みの元締めを許可する　sei　が必要です。
割り込みベクタに跳んでくるので処理ルーチンのラベルへジャンプ処理します。
●割り込みルーチンではフラグr3を立てるだけで、分岐はメインループで行っています。
●割り込み許可を常に可としていたら、点滅のウエイトルーチンのあるところで受け付けると不可解な挙動をしましたのでウエイトループのないところだけで許可しています。

前回と同じでウエイトルーチンがありますので極短く押したときは読まれないときがあります。
コードサイズは偶然に前回とまったく同じでした。
スイッチoffのときにチャタリングがあるのか、時々不安定な挙動を示します。プルアップしているスイッチ入力端子とGND間に0.1μFを入れると簡単に解決しました。ソフトで解決するには前回と比べねばなりませんのでやっかいになりそうです（やがては必要でしょうが）。
Ｃのif文を書くのにずいぶん考え込みます。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

９　タイマカウンタ割り込みのＬＥＤ点滅　

ウエイト（ディレイ）ルーチンによる点滅でなく、タイマーを使って１秒ごとにLEDを点滅するプログラムを意図しました。
timer1（16bit)を使いますが、スタートと同時にタイマーが動き始めて、１秒経ったら割り込みが起こってLEDの点灯が変わるものです。「特定の操作から１秒間」にはなっていません。あなたまかせの１秒です。

一つのLEDの点滅では芸がないので１秒ごとにシフト命令でPORTB0からPORETB7のLEDへ点灯を移動させます。
プログラムの目的はtimer1のオーバーフローによる割り込みの実験です。

AVRの機能には多くのレジスタが関係しています。使用言語に関係なく、レジスタ機能をデータシートから紙に書き出してプログラムを書いてきましたが、そのメモは再利用できるものではなく、次回にはまたまたデータシートと格闘になります。今回は少しの改善策として、プログラム冒頭のコメント欄にデータシートから取り出したレジスタ情報を少ないながらも書いてみることにしました。
関係のレジスタであっても意図する用途では不要なものもありますが、それも不要と書いてメモすることにします。

ポイント：
●タイマ・カウンタ１に次のレジスタが関係します。使い方によっては設定不要のものもあります。
　　TCCR1A (Timer/Counter1ControlRegisterA)
　　TCCR1B (Timer/Counter1ControlRegisterB) ﾀｲﾏ/ｶｳﾝﾀ1制御ﾚｼﾞｽﾀB
　　TCNT1H,TCNT1L(TCNT1)(Timer/Counter1) ﾀｲﾏ/ｶｳﾝﾀ1
　　OCR1AH,OCR1AL(OCR1A) (Timer/Counter1OutputCompareRegisterA)ﾀｲﾏ/ｶｳﾝﾀ1比較Aﾚｼﾞｽﾀ
　　OCR1BH,OCR1BL(OCR1B) (Timer/Counter1OutputCompareRegisterB)ﾀｲﾏ/ｶｳﾝﾀ1比較Bﾚｼﾞｽﾀ
　　ICR1H,ICR1L(ICR1) (Timer/Counter1InputCaptureRegister)ﾀｲﾏ/ｶｳﾝﾀ1捕獲(ｷｬﾌﾟﾁｬ)ﾚｼﾞｽﾀ
　　TIMSK (Timer/CounterInterruptMaskRegister)ﾀｲﾏ/ｶｳﾝﾀ割り込みﾏｽｸﾚｼﾞｽﾀ
　　TIFR (Timer/CounterInterruptFlagRegister) ﾀｲﾏ/ｶｳﾝﾀ割り込み要求ﾌﾗｸﾞﾚｼﾞｽﾀ
●16bitレジスタをアクセスするときは順序があります。書き込みは上位バイトから、読み取りは下位バイトからです。アクセス時は割り込みを禁止する必要があります。この例では sei の前の初期設定と、割り込みルーチン中で割り込みが禁止されているときに書き込んでいますから割り込み禁止を発行していません。
●タイマーはカウントアップして$0000になるときにオーバーフロー割り込みを発生しますから 65536-カウント数をタイマー値として代入しておきます。もちろん、オーバーフローした直後に繰り返し設定する必要があります。

タイマー割り込みで周期的な動作をさせる実験でした。考えていたとおりの結果が得られましたが、LED点滅だけの目的ならディレイルーチンを使うものと違いはないでしょう。他の仕事、例えばデータの取り込みなどをしながらLEDの点滅が必要なときには使えると思います。

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

10　ＬＥＤ点灯移動方向の切り換え　２つの割り込み　

前回のＬＥＤ点灯でスイッチを付加してトグル動作で点灯方向を切り換える動作を考えました。
点灯を移動するインターバルはタイマー割り込みで作り、さらにスイッチの読み込みはINT0の外部割り込みで行います。２つの割り込みを使うとどのように動くのかを実証したいと考えてこのプログラムをつくりました。なお、PORTD2(INT0)に付けたタクトスイッチにはチャタリング防止のためスイッチと並列に0.1μFを入れてあります。

入力スイッチではプルアップが必要です。これを忘れて割り込みが入らないのでしばらく悩みました。

稼働してスイッチを押すと確かに左向きの流れから右向きの流れに変わります。気をよくして何回もスイッチを押していると向きが変わらないときがでてきます。ときには数回続けて無視される場合があります。どうやら２つの割り込みが競合しているようです。スイッチの割り込みは信号の立ち下がりで起こりますからスイッチを押した瞬間だけしか実現しません。この瞬間がタイマー割り込みの最中で割り込み禁止になっていると無視状態になるようです。
タイマー割り込み処理ルーチンに　sei　を書いてもやはり起こります。タイマー割り込みが起こってsei実行までの間にスイッチ信号が入ると起こるのだと思います。ある瞬間だけに発生する割り込みを２つ設定するとこのようになることが避けられないように思います。どのように解決しているのでしょうか。

とにかく考えた結果、立ち下がりの割り込みをやめてローレベル割り込みに変更します。このままだとスイッチを押している間中割り込みが連続して発生しますから複数回押したのと同じ状態になってしまいます。そこで、フラッグを用意して最初の割り込みはレジスタの処理incをしますが、２回目以降はなにもせずに割り込みを抜けます。押し続けのときは最初の１回だけが処理され、あとは空回りで割り込みルーチンから抜けることができません。スイッチを放すとメインルーチンに戻り割り込み処理フラグがクリアされます。

これでスイッチが無視されることなく方向反転ができますが、反対にスイッチを押している間はタイマー割り込みができませんので正確なタイマーが必要なときはこの方法も取れなくなります。スイッチをポーリングにする以外に方法は無いのでしょうか。尤もこれは使用言語によらず同じ問題になると思います。
＜重大な訂正＞後になって使用したタクトスイッチが正常な動作をしないことがあるのを発見しました。問題のスイッチを正常なものに取り変えると衝突も起きずに動作しました。２つの瞬間が同時に起こるのは確率的にずいぶん低いのではないかと思ってはいたのですが。しかし、せっかく作りましたからもう一つのプログラムも書いておきます。

点灯方向の切り替えは確実になりました。当然の事ながらスイッチを押している間はLEDは移動しません。INT0の割り込みルーチンを繰り返すために他のルーチンは停止してしまうからです。

（追記）　２つの割り込みを使ってもこのケースでは問題ないようです。常に「問題がない」と言い切れないのはＣで書いた周波数カウンタがtimer0とtimer1が他の割り込み処理中に割り込みが起こって無視されるケースがあったからです。仮に無視されても重大なエラーにならない回路だと使えると思います。

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

11　ROM領域に定数を置く　
ROM領域（プログラム領域）にデータを置くことができます。今はまだbiteデータだけですが、そのデータの書き方と読み取り方を実験しました。意図したとおりに書けているか、読み出せているかを判断するためにLEDを２進８桁表示器をして使っています。スイッチを押すと順次データを読み出してLEDに表示します。読み出しにカウンタを付けて、データを読み出しきると元にもどるようにしました。

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

12　ＰＷＭ動作（LED点灯）　
高速PWNといわれる動作で、８ビットカウンタは0～255のカウントを繰り返しますが、このときでOCR0Aレジスタに設定した値（0～255）と一致したときにOC0A端子(PB2端子)がＬになり、カウントが255になるとこの端子がＨになります。OCR0Aレジスタの数値が小さいときはＬの期間が長くなり、デューティ比が小さい矩形波となります。
このレジスタの値を連続的に変えるとデューティ比が連続して変わる矩形波が生じますから、これでＬＥＤを点灯すると明るさが連続的に変化することになります。等比数列的に明るさを変えるためにROM域に定数を設定してその値でデューティ比を決めています。


;*************************************************************************************************************
; 01pwm1.asm  ＰＷＭのテスト  PB0のLEDの明るさを周期的に変える im
;
;mcu＝Tn2313  RC 8MHz
;ハードウエアはPB0～7にLEDアレイを接続（Hで点灯）
;              PD2(INT0)にタクトsw(GNDへ)
;
;高速PWNでは、関係レジスタをセットして、OCR0Aにデューティ値1～255を書き込めば
;OC0A(PB2端子)に結果が出力される。
;
;人の目には明るさは等比数列的に見えるらしく、等差数列で変化するとデューティが小さいところ
;だけしか変化がわからない。  そこで .dbを使って等比数列的な数値列を記録して、その読み出しで
;デューティを変えている。一様な全範囲で明るさの変化が見える。
;
;
;高速PWMを使う。(WGM02～0=011または111)
;  ｶｳﾝﾀはBOTTOMからTOPまで計数。TOPはWGM02～0=011時に$FF、WGM02～0=111時にOCR0A。
;  非反転比較出力動作(COM0x1～0=10)では比較出力(OC0x)は TCNT0とOCR0xが一致したときｸﾘｱ(0)、BOTTOMでｾｯﾄ(1)。
;  反転出力動作(COM0x1～0=11)は一致したときｾｯﾄ(1)され、BOTTOMでｸﾘｱ(0)。
;
;ﾀｲﾏ/ｶｳﾝﾀ0制御ﾚｼﾞｽﾀA(Timer/Counter0ControlRegisterA)TCCR0A
;    ⑦COM0A1 ⑥COM0A0  ⑤COM0B1  ④COM0B0  ③ -    ② -    ①WGM01  ◎WGM00
;       1         0                                             1        1     
;ﾀｲﾏ/ｶｳﾝﾀ0制御ﾚｼﾞｽﾀB(Timer/Counter0ControlRegisterB)TCCR0B
;    ⑦FOC0A  ⑥FOC0B   ⑤-       ④-       ③WGM02  ②CS02   ①CS01  ◎CS00
;                                               0       0        1       0         I/O分周 8
;ﾀｲﾏ/ｶｳﾝﾀ0(Timer/Counter0)TCNT0
;    ⑦(MSB)  ⑥       ⑤       ④       ③       ②       ①       ◎(LSB)
;
;ﾀｲﾏ/ｶｳﾝﾀ0比較Aﾚｼﾞｽﾀ(Timer/Counter0OutputCompareARegister)OCR0A
;    ⑦(MSB)  ⑥       ⑤       ④       ③       ②       ①       ◎(LSB)
;
;ﾀｲﾏ/ｶｳﾝﾀ0比較Bﾚｼﾞｽﾀ(Timer/Counter0OutputCompareBRegister)OCR0B
;    ⑦(MSB)  ⑥       ⑤       ④       ③       ②       ①       ◎(LSB)
;
;ﾀｲﾏ/ｶｳﾝﾀ割り込みﾏｽｸﾚｼﾞｽﾀ(Timer/CounterInterruptMaskRegister)TIMSK
;    ⑦TOIE1  ⑥OCIE1A  ⑤OCIE1B  ④-      ③ICIE1  ②OCIE0B  ①TOIE0  ◎OCIE0A
;                                                                         1        一致割り込みA許可
;ﾀｲﾏ/ｶｳﾝﾀ割り込み要求ﾌﾗｸﾞﾚｼﾞｽﾀ(Timer/CounterInterruptFlagRegister)TIFR
;    ⑦TOV1   ⑥OCF1A    ⑤OCF1B   ④-      ③ICF1   ②OCF0B   ①TOV0   ◎OCF0A
;                                                                                   設定しない
;今回必要な設定は
;  sei
;  TCCR0A=0b1000_0011
;  TCCR0B=0b0000_0010
;  OCR0A =デューティ設定値
;  TIMSK =0b0000_0001
;
;
;
;使用レジスタ
;  z   データアドレス設定用
;  r16 汎用
;  r17 .db読み取り回数カウント用
;  r22 ディレイルーチン設定用
;  r0,r1,r2 ディレイルーチン用
;
;***************************************************************************************************************

.include "tn2313def.inc"      ;" "は半角の＜＞が本来なのですがhtmlのため""を使っています。

;===== 割り込みベクタの設定  ==========================================
.cseg
.org 0
    rjmp reset                ;各種ﾘｾｯﾄ  下の reset: ラベルへジャンプする
.org 13
    rjmp tim0_compa           ;ﾀｲﾏ/ｶｳﾝﾀ0比較A一致 
    
;===== プログラム本体 =====================================================
.org 20                       ;20番地から次のﾌﾟﾛｸﾞﾗﾑが始まる
data:
    .db   1,  2,  4,  4,  5,  6,  8, 10, 12, 14
    .db  17, 21, 25, 31, 37, 45, 55, 67, 81, 98
    .db 119,145,177,214,255,255,214,177,145,119
    .db  98, 81, 67, 55, 45, 37, 31, 25, 21, 17
    .db  14, 12, 10,  8,  6,  5,  4,  4,  2,  1

reset:
    ldi  r16,low(ramend)      ;RAM最終ｱﾄﾞﾚｽ下位を取得
    out  spl,r16              ;ｽﾀｯｸﾎﾟｲﾝﾀ(下位)を初期化

    ldi  r16,0b1000_0011      ;TCCR0A=0b1000_0011
    out  TCCR0A,r16           ;
    
    ldi  r16,0b0000_0010      ;TCCR0B=0b0000_0010
    out  TCCR0B,r16           ;
    
    ldi  r16,128              ;OCR0A =デューティ設定値
    out  OCR0A,r16            ;必要ない。mainですぐに再設定
    
    ldi  r16,0b0000_0001      ;TIMSK =0b0000_0001
    out  TIMSK,r16            ;割り込みマスク
    
    ldi  r16, 0b11111111      ;PORTBの設定(出力)
    out  DDRB, r16            ;DDRBに直接書けない

main:
    ldi r17,50                 ;デューティデータ読み取り回数
    sei                       ;全割り込み許可
    ldi  zl, low(data+data)   ;zレジスタ初期設定
    ldi  zh, high(data+data)  ;ROMのアドレスはバイトではなくワード単位である。
    
loop:
                              ;main_loopではなにもしない。割り込みルーチンで。
    rjmp loop                 ;
    
tim0_compa:                   ;タイマカウンタ比較割り込み
    lpm  r16, z+              ;読み取り後インクリメントされる
    out  OCR0A,r16            ;デューティ値を OCR0Aに設定
    
    ldi r22,5                 ;20msに設定 この値が光度変化の速さを決める
    rcall delay10ms           ;ウエイト呼び出し
                              ;
    dec  r17                  ;データ読み出しカウンタdec
    breq restart              ;0か？
    reti                      ;0でなければ抜ける
restart:                      ;0のときはデータ読み出し再設定
    ldi r17, 50               ;
    ldi  zl, low(data+data)   ;zレジスタ初期設定
    ldi  zh, high(data+data)  ;ROMのアドレスはバイトではなくワード単位である。
    reti                      ;
     

delay10ms:                    ;////////// 10ミリ秒サブルーチン //////////
    mov  r2,  r22             ;r22から引数を得る  r22=1の時20ms
dly2:                         ;
    ldi  r22, 100             ;
    mov  r1,  r22             ;
dly1:                         ;
    ldi  r22, 200             ;
    mov  r0,  r22             ;
dly0:                         ;
    nop                       ;1クロック
    dec  r0                   ;1クロック
    brne dly0                 ;2クロック  合計４クロック
    dec  r1                   ;
    brne dly1                 ;
    dec  r2                   ;
    brne dly2                 ;
    ret                       ;サブルーチンの終了＝呼び出しルーチンへ復帰

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

13　ＳＲＡＭに置くbyte型変数　
.dseg の 0x60番地以降はSRAM領域です。　ここに ラベル:　.byte　個数　を書くとbyte型変数の領域が確保されます。初期化は行われません。プログラム中の書き出し（代入）はラベルの番地をｚレジスタにldiして、レジスタからstでします。読み出し（参照）は同じくｚレジスタにラベルの番地を入れて、レジスタに ld で行います。ｚにはＺ+ や -Ｚも使えます。

この実験プログラムでは２つの数値を２つの変数に代入し、その後、１番目の変数を読み出してLEDに表示して、１秒のインターバルで、標識の0xaaを表示、続いて２つ目の変数をLEDに表示するものです（表示は無限ループになっています）。


;*****************************************************************
; 02dseg1.asm  SRAMにBYTE型変数を置くim
;
;目的：SRAM上の変数を定義して、読み書きを行う。
;      ２byteのbyte型変数を置く
;
;mcu＝Tn2313  RC 8MHz
;ハードウエアはPB0～7にLEDアレイを接続（Hで点灯）
;              PD2(INT0)にタクトsw(GNDへ)
;
;変数は次のように定義する（置く）。
;  .dseg
;  .org 0x60                     ;SRAMはこの番地から
;  data:
;      .byte  2                  ;byte型２個
;  読み取り
;  .cseg
;      ldi  zl,low(data)         ;
;      ldi  zh,high(data)        ;
;      ld   r16,z                ;z+,-zも使える
;  書き込み
;      ld   zh,high(data)        ;
;      ld   zl,low(data)         ;
;      st   z,  r16              ;メモリへはストア命令
;
;実験プログラムは  (data)に65を書き、(data+1)に127を書く。
;続いて、(data)を読み出してLEDに１秒間表示し、中間に$aaを表示した後に
;(data+1)を表示する。
;
;
;使用レジスタ
;  z   データアドレス設定用
;  r16 汎用
;  r22 ディレイルーチン設定用
;  r0,r1,r2 ディレイルーチン用
;
;*****************************************************************

.include "tn2313def.inc"      ;" "は半角の＜＞が本来なのですがhtmlのため""を使っています。

;===== 割り込みベクタの設定  ==========================================
.cseg
.org 0
    rjmp reset                ;各種ﾘｾｯﾄ  下の reset: ラベルへジャンプする
    
;===== プログラム本体 =====================================================
.dseg
.org 0x60
data:
    .byte 2                    ;ラベルdataにbyte型変数を２個置く

.cseg
.org 20                       ;20番地から次のﾌﾟﾛｸﾞﾗﾑが始まる

reset:
    ldi  r16,low(ramend)      ;RAM最終ｱﾄﾞﾚｽ下位を取得
    out  spl,r16              ;ｽﾀｯｸﾎﾟｲﾝﾀ(下位)を初期化

    ldi  r16, 0b11111111      ;PORTBの設定(出力)
    out  DDRB, r16            ;DDRBに直接書けない

main:
    ldi  r16, 67              ;
    ;書き込み
    ldi  zh,high(data)        ;変数の番地を２回に分けて
    ldi  zl,low(data)         ;ｚレジスタに読む
    st   z,  r16              ;ｚレジスタ間接でr16を書き出す

    ldi  r16, 127             ;
    ;書き込み
    ldi   zh,high(data+1)     ;変数の２番目を指定
    ldi   zl,low(data+1)      ;
    st   z,  r16              ;

    ;読み取り
    ldi  zl,low(data)         ;変数の番地を２回に分けて
    ldi  zh,high(data)        ;ｚレジスタに読む
    ld   r16,z                ;ｚ間接指定で読みとる
    out  PORTB, r16           ;LEDに表示
    ldi  r22,100              ;
    rcall delay10ms           ;
    
    ldi  r16,0xaa             ;
    out  PORTB, r16           ;
    ldi  r22,100              ;
    rcall delay10ms           ;
    
    
    ;読み取り
    ldi  zl,low(data+1)       ;
    ldi  zh,high(data+1)      ;
    ld   r16, z               ;
    out  PORTB, r16           ;
    ldi  r22,100              ;
    rcall delay10ms           ;
    rjmp main                 ;


delay10ms:                    ;////////// 10ミリ秒サブルーチン //////////
    mov  r2,  r22             ;r22から引数を得る  r22=1の時20ms
dly2:                         ;
    ldi  r22, 100             ;
    mov  r1,  r22             ;
dly1:                         ;
    ldi  r22, 200             ;
    mov  r0,  r22             ;
dly0:                         ;
    nop                       ;1クロック
    dec  r0                   ;1クロック
    brne dly0                 ;2クロック  合計４クロック
    dec  r1                   ;
    brne dly1                 ;
    dec  r2                   ;
    brne dly2                 ;
    ret                       ;サブルーチンの終了＝呼び出しルーチンへ復帰

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

14　Ｃから呼び出す delay関数　
１ms単位のdelay関数をアセンブラで書いてみました。AVRwiki　と　ChaNさんの記事を参考に書いてみたところうまく動きました。
まねをして書いてみたものですから、書き方におかしなところがあるかもしれません。
１MHzを基準にしていますから、12MHzクロックで 8ms 必要なときは　delay_ms1(8*12) の様に12倍して呼び出します。引数は uint16_t ですから掛け算した後の数値が56635まで可能です。コンパイラの最適化には関係しないと思います。

Ｃのプログラムでは　void delay_ms1(uint16_t);　とプロトタイプ宣言しておく方がいいようです。
コンパイルは　Ｃプログラムと同じディレクトリに置いて、makefileの　ASRC =　に delay_ms1.S と書くとmakeでアセンブルとリンクが行われます。



;*******************************************************************************
;delay_ms1.S  クロック1MHzの時１msのdelayルーチン  2008.12.13 im
;呼び出しは delay_ms1(15*8); 8MHzクロックで15msのとき。引数はuint16_t。
;コンパイル時にmakefileの  ASRC =に delay_ms1.S と書く。 
;Ｃプログラムに void delay_ms1(uint16_t); と宣言する。なくても可。
;*******************************************************************************
				//拡張子を.SにすればCプリプロセッサにも掛けられるので、
				//C++方式のコメントが利用できる
.global delay_ms1			//delay_ms1を外部から利用可能にする
.func delay_ms1			// 関数名の宣言。この後に書かれるアセンブラ命令が関数
				//の中身になる
delay_ms1:			//関数の開始
2:	ldi	r18,250		//r18--r25は自由に使える
1:	nop			//時間合わせ
	dec	r18
	brne	1b		//0でなければ後方の1:へ
	sbiw	r24,1		//r25,r24ペアに引数が入っている
	brne	2b		//0でなければ後方の2:へ
	ret
.endfunc

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　

TOPページへもどる

　　　　　　　　　　　　　　　　　　　　　　　　　　↑　