コンピュータで使用中のディスクドライブの情報を表示してみましょう。新規に開いたブック、またはシートで実行します。

Sub ディスクドライブ情報を表示()
  Dim objFS, objDrv
  Dim i As Integer
  Set objFS = CreateObject("Scripting.FileSystemObject")
  Cells.ClearContents
  Range("A1").Value = "ドライブ名"
  Range("B1").Value = "ドライブの種類"
  Range("C1").Value = "利用可能"
  Range("D1").Value = "ボリューム名"
  Range("E1").Value = "シリアルナンバー"
  Range("F1").Value = "ファイルシステム"
  Range("G1").Value = "総容量"
  Range("H1").Value = "使用可能な容量"
  Range("I1").Value = "使用率"
  i = 1
  For Each objDrv In objFS.Drives
    i = i + 1
    With objDrv
      Cells(i, 1).Value = .DriveLetter
      Select Case .DriveType
        Case 0: Cells(i, 2).Value = "不明"
        Case 1: Cells(i, 2).Value = "リムーバブル ディスク"
        Case 2: Cells(i, 2).Value = "ハード ディスク"
        Case 3: Cells(i, 2).Value = "ネットワーク ドライブ"
        Case 4: Cells(i, 2).Value = "CD-ROM"
        Case 5: Cells(i, 2).Value = "RAM ディスク"
      End Select
      Cells(i, 3).Value = .IsReady
      If .IsReady Then
        Cells(i, 4).Value = .VolumeName
        Cells(i, 5).Value = .SerialNumber
        Cells(i, 6).Value = .FileSystem
        Cells(i, 7).Value = FormatNumber(.TotalSize / 1024, 0) & "KB"
        Cells(i, 8).Value = FormatNumber(.AvailableSpace / 1024, 0) & "KB"
        Cells(i, 9).Value = ((.TotalSize - .AvailableSpace) / .TotalSize) * 100 & "%"
      End If
    End With
  Next
  Columns.AutoFit
End Sub

VBScriptを使ってドライブ情報を取得しています。利用できるプロパティは他に、

• [ FreeSpace ]　 ユーザーが使用できるディスクの空き境域
• [ ShareName ]　ネットワーク共有名