/* Lagrange Interpolation */
/* Data from Holton(2003)"Value-at-Risk" */
new; cls;
let data[10,2]=
1.1  2.14
1.4  2.60
2.5  1.15
2.7  1.19
3.2  1.88
3.6  1.55
4.1  2.65
4.3  3.80
4.5  4.46
4.9  6.35
;
x=data[.,1]; y=data[.,2];
points=9;                                             /* # of points between x[k] and x[k+1] */
call lagrangeinterp(y,x,points);




proc lagrangeinterp(y,x,points);
   local z,n,xx,yy,x1,i;
/* sort them out in terms of x */
   z=x~y;
   z=sortc(z,1);
   x=z[.,1];
   y=z[.,2];
   n=rows(x);
/* graph */
   xx=zeros((points+1)*(n-1)+1,1);
   yy=zeros((points+1)*(n-1)+1,1);
   i=1;
   do while i<=n-1;
      x1=seqa(x[i],(x[i+1]-x[i])/(points+1),points+1);
      xx[(i-1)*(points+1)+1:i*(points+1)]=x1;
      i=i+1;
   endo;
   xx[rows(xx)]=x[n];
   i=1;
   do while i<=rows(yy);
      yy[i]=lagrange(y,x,xx[i]);
      i=i+1;
   endo;
   library pgraph;
   graphset;
   pqgwin auto;
   begwind;
   window(1,1,0);
   scale(-0.05*(maxc(x)-minc(x))+minc(x)|maxc(x)+0.05*(maxc(x)-minc(x)),-0.25*(maxc(y)-minc(y))+minc(y)|maxc(y)+0.25*(maxc(y)-minc(y)));
   setwind(1);
      title("Lagrange Interpolation");
      xy(xx,yy);
   setwind(1);
      _plctrl=-1;
      _pcolor=15;
      _psymsiz=1;
      xy(x,y);
   endwind;
   retp(xx~yy);
endp;

proc lagrange(y,x,x0);
   local z,n,j,i,Fx;
/* sort them out in terms of x */
   z=x~y;
   z=sortc(z,1);
   x=z[.,1];
   y=z[.,2];
   n=rows(x);
/* calculation of F(x) */
   Fx=y;                 /* as a vector */
   j=1;
   do while j<=n;
      i=1;
      do while i<=n;
         if i/=j;
            Fx[j]=Fx[j]*(x0-x[i])/(x[j]-x[i]);
         endif;
         i=i+1;
      endo;
      j=j+1;
   endo;
   Fx=sumc(Fx);          /* sum them up */
   retp(Fx);
endp;