new; cls;
/* Stochastic Trinomial alpha-percentile Call Options */
S0=50;
K=50;
r=0.10;
sig=0.40;
T=5/12;
alpha=0.75;
nn=500;
times=5000;


print/lz "     nn=" nn;
print/lz "  times=" times;
print/lz "  alpha=" alpha;
print "floating strike:";
print "C=" PTalphapC(S0,r,sig,T,nn,alpha,times);
print;
print "fixed strike:";
print "C=" PTalphapCf(S0,K,r,sig,T,nn,alpha,times);




/*
**  ptalphap.txt - Stochastic Trinomial alpha-percentile(Floating Strike) Call Options.
** (C) Copyright 2005 Yosuke Amijima. All Rights Reserved.
**
**  Purpose:    Calculates alpha-percentile option prices by stochastic trinomial simulation.
**
**  Format:     C=PTalphapCf(S0,r,sig,T,nn,alpha,times);
**              
**
**  Input:      S0       scalar,  initial value
**             
**              r        scalar,  risk-free interest rate
**
**              sig      scalar,  volatility
**
**              T        scalar,  maturity
**
**              nn       scalar,  number of time steps
**
**              alpha    scalar,  percentile ( 0 <= alpha <= 1 )
**
**              times    scalar,  number of simulations
**
**
**  Output:     C        scaler,  call option price
**
*/

proc PTalphapC(S0,r,sig,T,nn,alpha,times);
   local OV,i,S,STT,C;
   OV=zeros(times,1);
   i=1;
   do while i<=times;
      S=ptsampler(S0,r,sig,T,nn);
      STT=S[nn+1];
      S=S[2:nn+1];
      S=sortc(S,1);
      if round(nn*alpha)==0;
          OV[i]=STT-S[1];
      else;
          OV[i]=STT-S[round(nn*alpha)];
      endif;
      i=i+1;
   endo;
   C=exp(-r*T)*meanc(maxc((OV~zeros(times,1))'));
   retp(C);
endp;

/*
**  ptalphap.txt - Stochastic Trinomial alpha-percentile(Fixed Strike) Call Options.
** (C) Copyright 2005 Yosuke Amijima. All Rights Reserved.
**
**  Purpose:    Calculates alpha-percentile option prices by stochastic trinomial simulation.
**
**  Format:     C=PTalphapCf(S0,K,r,sig,T,nn,alpha,times);
**              
**
**  Input:      S0       scalar,  initial value
**
**              K        scalar,  strike price
**             
**              r        scalar,  risk-free interest rate
**
**              sig      scalar,  volatility
**
**              T        scalar,  maturity
**
**              nn       scalar,  number of time steps
**
**              alpha    scalar,  percentile ( 0 <= alpha <= 1 )
**
**              times    scalar,  number of simulations
**
**
**  Output:     C        scaler,  call option price
**
*/

proc PTalphapCf(S0,K,r,sig,T,nn,alpha,times);
   local OV,i,S,C;
   OV=zeros(times,1);
   i=1;
   do while i<=times;
      S=ptsampler(S0,r,sig,T,nn);
      S=S[2:nn+1];
      S=sortc(S,1);
      if round(nn*alpha)==0;
          OV[i]=S[1]-K;
      else;
          OV[i]=S[round(nn*alpha)]-K;
      endif;
      i=i+1;
   endo;
   C=exp(-r*T)*meanc(maxc((OV~zeros(times,1))'));
   retp(C);
endp;


/*
**  ptsampler.txt - Stochastic Trinomial Path Sampler.
** (C) Copyright 2005 Yosuke Amijima. All Rights Reserved.
**
**  Purpose:    Gets a stochastic path on trinomial tree.
**
**  Format:     S=ptsampler(S0,r,sig,T,nn)
**
**  Input:      S0       scalar,    initial value
**
**              r        scalar,    risk-free interest rate
**
**              sig      scalar,    volatility
**
**              T        scalar,    maturity
**
**              nn       scalar,    number of time steps
**
**
**  Output:     S        vector,    (nn+1) x 1 of resulting values including S0
**
**  Notice:     This procedure uses 'ptrisampler' inside.
**
*/
proc ptsampler(S0,r,sig,T,nn);
   local delt,pd,pm,pu,p,S,u;
   delt=T/nn;
   pd=-sqrt(delt/(12*sig^2))*(r-1/2*sig^2)+1/6;
   pm=2/3;
   pu=sqrt(delt/(12*sig^2))*(r-1/2*sig^2)+1/6;
   p=pu|pm|pd;
   S=ptrisampler(p,nn);
   S=S-1;
   u=exp(sig*sqrt(3*delt));
   S=S0*u^cumsumc(S);
   S=S0|S;
   retp(S);
endp;

/*
**  ptrisampler.txt - Stochastic Trinomial 0-1-2 Sampler.
** (C) Copyright 2005 Yosuke Amijima. All Rights Reserved.
**
**  Purpose:    Gets stochastic Trinomial 0-1-2 index numbers in a very easy way.
**
**  Format:     x=ptrisampler(p,nr);
**
**  Input:      p        vector,    3 x 1 of probability vector(p[1] for 2, p[2] for 1, p[3] for 0)
**
**              nr       scalar,    number of rows
**
**
**  Output:     x        vector,    nr x 1 of resulting 0-1 index vector
**
*/
proc ptrisampler(p,nr);
   local x;
   p=cumsumc(p);
   x=rndu(nr,1);
   x=2*(x.<=p[1])+1*(x.>p[1] .and x.<=p[2]);
   retp(x);
endp;