/* Farlie-Gumbel-Morgenstern Copula ( C(u,v)=u.*v.*(1+theta*(1-u).*(1-v)) ) */
/* Solve q=v.*(1+theta-2*theta*u-theta*v+2*theta*u.*v) (=Cu) in terms of v. */
/*                                                (Latin Hypercube version) */         
new; cls;
theta=-0.99;
nn=30;          /* n=nn^2 */
U=Cfgm(theta,nn);

library pgraph;
graphset;
_plctrl=-1;
xy(U[.,1],U[.,2]);


proc Cfgm(theta,nn);
   local dim,UU,u,q,a,b,c,v;
   if theta<=-1 or theta>=1;
      errorlog "ERROR: Parameter theta must be -1<theta<1.";
      retp(".");
   endif;
   dim=2;
   UU=LHss(nn,dim);
   u=UU[.,1];
   q=UU[.,2];
   if theta==0;
      v=q;
   else;
      a=2*theta*u-theta; b=1+theta-2*theta*u; c=-q;
      v=1./(2*a).*(-b+sqrt(b^2-4*a.*c));
   endif;
   retp(u~v);
endp;


/*
**  LHss.txt - Latin Hypercube U(0,1).
** (C) Copyright 2005 Yosuke Amijima. All Rights Reserved.
**
**  Purpose:    Calculates Latin Hypercube numbers in a very easy way. new algorithm.
**
**  Format:     x=LHss(nn,dim);
**
**  Input:      nn       scalar,    max number of index  (1,2,3,...,nn)
**
**              dim      scalar,    dimension            (1,...,dim)
**
**
**  Output:     x        matrix ,   (nn^dim) x (dim) of resulting U(0,1) numbers
**
**  Notice:     It takes lots of memory to run. Light version of GAUSS will not work in most cases.
*/
proc LHss(nn,dim);
   local x,b,n,z,y,indexvec,d,U,i,index;
/* convert x(base 10) to y(base b) */
   x=seqa(1,1,nn^dim-1); 
   b=nn;
   n=maxc(log(x)/log(b))+1;
   z=reshape(b,n,rows(x));
   y=rev(recserrc(x,z))';
   indexvec=y+1;                     /* shift all elements by 1    */
   indexvec=ones(1,dim)|indexvec;    /* insert 1's at the 1st row  */
/* divide between 0 and 1 into nn segments and sample from each segment */
   d=1/nn;
   U=(d*indexvec-d*(indexvec-1)).*rndu(nn^dim,dim)+d*(indexvec-1);
   do while NOT(U>0);                                                      /* check if U contains 0's */
      U=(d*indexvec-d*(indexvec-1)).*rndu(nn^dim,dim)+d*(indexvec-1);
   endo;
/* randomize the order as a row */
   x=zeros(nn^dim,dim);
   i=1;
   do while i<=nn^dim-1;
      index=ceil((nn^dim-(i-1))*rndu(1,1));
      x[i,.]=U[index,.];
      if index==1;
         U=U[2:rows(U),.];
      elseif index==rows(U);
         U=U[1:rows(U)-1,.];
      else;
         U=U[1:(index-1) (index+1):rows(U),.];
      endif;
      i=i+1;
   endo;
   x[nn^dim,.]=U;
   retp(x);
endp;