/* Gumbel Copula in Archimedean Family ( phi(u)=(-ln(u))^theta ) */
new; cls;
theta=1.5;
n=1000;
U=Cgumbel(theta,n);

library pgraph;
graphset;
_plctrl=-1;
xy(U[.,1],U[.,2]);



proc Cgumbel(theta,n);
   local s,q,t,u,v;
   if theta<1;
      errorlog "ERROR: Parameter theta must be greater than or equal to 1.";
      retp(".");
   endif;
   s=rndu(n,1);
   q=rndu(n,1);
   t=calct(q,theta);
   u=phi_1(s.*phi(t,theta),theta);
   v=phi_1((1-s).*phi(t,theta),theta);
   retp(u~v);
endp;

proc calct(q,theta);
   local tstar,tstarstar,i,t,x;
   tstar=zeros(rows(q),1);
   i=1;
   do while i<=rows(q);
      t=seqa(0.0001,0.0001,10000);
      x=abs(q[i]-(t-phi(t,theta)./phi1(t,theta)));
      tstar[i]=t[minindc(x)];
      t=seqa(tstar[i]-0.00005,0.00000001,10000);
      x=abs(q[i]-(t-phi(t,theta)./phi1(t,theta)));
      tstarstar=t[minindc(x)];
      if tstarstar==tstar[i]-0.00005;
         t=seqa(0.00000001,0.00000001,10000);
         x=abs(q[i]-(t-phi(t,theta)./phi1(t,theta)));
         tstar[i]=t[minindc(x)];
      else;
         tstar[i]=tstarstar;
      endif;
      if tstarstar>1;
         tstar[i]=1;
      endif;
      i=i+1;
   endo;
   retp(tstar);
endp;


fn phi(u,theta)=(-ln(u))^theta;

fn phi1(u,theta)=theta*(-ln(u))^(theta-1).*(-1/u);

fn phi_1(u,theta)=exp(-u^(1/theta));