/* ARCH(q)_GED(nu) */
new; cls;
a0=0.001;
a={0.3,0.2,0.1,0.1,0.1,0.1};               
n=1000;
nu=1;
u=arch_GED(a0,a,nu,n);
library pgraph;
graphset;
title("ARCH(q)_GED(nu)");
t=seqa(1,1,n);
xy(t,u);



proc arch_GED(a0,a,nu,n);
   local cutn,e,s2,q,u,h,t;
   if a0<=0;
      errorlog "ERROR:Parameter a0 must be positive.";
      retp(".");
   endif;
   if not a>=0;
      errorlog "ERROR:Each element of a must be non negative.";
      retp(".");
   endif;
   cutn=100;                  /* first some data to cut off */
   e=rndged0(nu,cutn+n);                                      /* Now, e~GED(nu). */
   s2=a0/(1-sumc(a));
   q=rows(a);
   print/lz "q=" rows(a);
   u=zeros(cutn+n,1);
   h=zeros(cutn+n,1);
   u[1:q]=sqrt(s2)*e[1:q];
   t=q+1;
   do while t<=cutn+n;
      h[t]=a0+rev(a)'(u[t-q:t-1]^2);
      u[t]=sqrt(h[t])*e[t];
      t=t+1;
   endo;
   u=u[cutn+1:cutn+n];
   retp(u);
endp;

proc rndged0(nu,n);
   local lowerbound,upperbound,max,x,i,y,U;
   lowerbound=-4; upperbound=4;            /* You could change, but normally O.K. */
   max=pdfged(0,nu);
/* acceptance-rejection method */
   x=zeros(n,1);
   i=1;
   do while i<=n;
      y=(upperbound-lowerbound)*rndu(1,1)+lowerbound;
      U=rndu(1,1);
      if U<=pdfged(y,nu)/max;
         x[i]=y;
         i=i+1;
      endif;
   endo;
   retp(x);
endp;

proc pdfged(x,nu);
   local lambda;
   if nu<=0;
      errorlog "ERROR: Parameter nu must be positive.";
      retp(".");
   endif;
   lambda=1/2^(1/nu).*(gamma(1/nu)./gamma(3/nu))^(1/2);
   retp( nu.*exp(-1/2*abs(x./lambda)^nu)./(lambda.*2^(1+1/nu).*gamma(1/nu)) );
endp;