/* IGARCH(p,q) */
new; cls;
a0=0.001;
a={0.2,0.1,0.1}; b={0.3,0.1,0.1,0.1};             
n=1000;
u=igarch(a0,a,b,n);
library pgraph;
graphset;
title("IGARCH(p,q)");
t=seqa(1,1,n);
xy(t,u);


proc igarch(a0,a,b,n);
   local cutn,e,s2,q,p,u,h,max,t;
   if a0<=0;
      errorlog "ERROR:Parameter a0 must be positive.";
      retp(".");
   endif;
   if not a>=0;
      errorlog "ERROR:Each element of a must be non negative.";
      retp(".");
   endif;
   if not b>=0;
      errorlog "ERROR:Each element of b must be non negative.";
      retp(".");
   endif;
   if sumc(a)+sumc(b)/=1;
      errorlog "ERROR:Parameter sum of a+b must be 1.";
      retp(".");
   endif;
   cutn=1000;                  /* first some (longer) data to cut off */
   e=rndn(cutn+n,1);   
   s2=a0;                      /* some constant to start, for example, a0. */
   q=rows(a); p=rows(b);
   print/lz "q=" q;; print/lz "p=" p;
   u=zeros(cutn+n,1);
   h=zeros(cutn+n,1);
   max=maxc(q|p);
   u[1:max]=sqrt(s2)*e[1:max]; h[1:max]=s2*ones(max,1);
   t=max+1;
   do while t<=cutn+n;
      h[t]=a0+rev(a)'(u[t-q:t-1]^2)+rev(b)'h[t-p:t-1];
      u[t]=sqrt(h[t])*e[t];
      t=t+1;
   endo;
   u=u[cutn+1:cutn+n];
   retp(u);
endp;