/* Henderson's 9-term Moving Average */
new; cls;
let data[50,1]=
      60
      61
      60
      62
      60
      63
      64
      65
      69
      70
      69
      66
      64
      64
      62
      64
      65
      55
      53
      57
      60
      58
      63
      63
      63
      68
      69
      69
      68
      69
      70
      67
      66
      67
      68
      69
      69
      77
      80
      80
      78
      76
      76
      72
      71
      70
      73
      71
      78
      80
;
data=rev(data);               /* original data in reverse order */
t=seqa(1,1,rows(data));

library pgraph;
graphset;
_pltype=6;
_plegctl=1;
_plegstr="actual\000Henderson 9";
title("Henderson 9");
xy(t,data~henderson9(data));







proc henderson9(x);
   local w,t,k,i,m,w1,w2,w3,w4;
/* Symmetric part in the middle */
   w={0.33,0.267,0.119,-0.010,-0.041};
   t=rows(x);
   k=rows(w)-1;
   w=rev(w[2:k+1])|w;
   m=zeros(rows(x),cols(x));
   i=k+1;
   do while i<=t-k;
      m[i,.]=w'x[i-k:i+k,.];
      i=i+1;
   endo;
/* Asymmetric part at end points */
   w1={-0.156,-0.034,0.185,0.424,0.581}; 
   w2={-0.049,-0.011,0.126,0.282,0.354,0.298};
   w3={-0.022,0,0.12,0.259,0.315,0.242,0.086};
   w4={-0.031,-0.004,0.12,0.263,0.324,0.255,0.102,-0.029};
   m[1,.]=rev(w1)'x[1:k+1,.]; m[t,.]=w1'x[t-k:t,.];
   m[2,.]=rev(w2)'x[1:k+2,.]; m[t-1,.]=w2'x[t-k-1:t,.];
   m[3,.]=rev(w3)'x[1:k+3,.]; m[t-2,.]=w3'x[t-k-2:t,.];
   m[4,.]=rev(w4)'x[1:k+4,.]; m[t-3,.]=w4'x[t-k-3:t,.];
   retp(m);
endp;